MrPiglr
9dddce666d
- Forked from Godot Engine 4.7-dev (MIT License) - Rebranded to AeThex Engine with cyan/purple theme - Added AI-powered development assistant module - Integrated Claude API for code completion & error fixing - Custom hexagon logo and branding - Multi-platform CI/CD (Windows, Linux, macOS) - Built Linux editor binary (151MB) - Complete source code with all customizations Tech Stack: - C++ game engine core - AI Module: Claude 3.5 Sonnet integration - Build: SCons, 14K+ source files - License: MIT (Godot) + Custom (AeThex features) Ready for Windows build via GitHub Actions!
63 lines
1.8 KiB
Python
63 lines
1.8 KiB
Python
#!/usr/bin/env python
|
|
from misc.utility.scons_hints import *
|
|
|
|
Import("env")
|
|
|
|
# If we're using Metal, we need metal-cpp.
|
|
env.Prepend(CPPPATH=["#thirdparty/metal-cpp/"])
|
|
|
|
env_metal = env.Clone()
|
|
|
|
# Thirdparty source files
|
|
|
|
thirdparty_obj = []
|
|
|
|
thirdparty_spirv_headers_dir = "#thirdparty/spirv-headers/"
|
|
thirdparty_dir = "#thirdparty/spirv-cross/"
|
|
thirdparty_sources = [
|
|
"spirv_cfg.cpp",
|
|
"spirv_cross.cpp",
|
|
"spirv_parser.cpp",
|
|
"spirv_msl.cpp",
|
|
"spirv_reflect.cpp",
|
|
"spirv_glsl.cpp",
|
|
"spirv_cross_parsed_ir.cpp",
|
|
"spirv_cross_util.cpp",
|
|
]
|
|
thirdparty_sources = [thirdparty_dir + file for file in thirdparty_sources]
|
|
|
|
# Include metal-cpp
|
|
thirdparty_sources += [
|
|
"#thirdparty/metal-cpp/metal_cpp.cpp",
|
|
]
|
|
|
|
env_metal.Prepend(CPPPATH=[thirdparty_dir, thirdparty_dir + "/include"])
|
|
env_metal.Prepend(CPPPATH=[thirdparty_spirv_headers_dir + "include/spirv/unified1"])
|
|
|
|
# Must enable exceptions for SPIRV-Cross; otherwise, it will abort the process on errors.
|
|
if "-fno-exceptions" in env_metal["CXXFLAGS"]:
|
|
env_metal["CXXFLAGS"].remove("-fno-exceptions")
|
|
env_metal.Append(CXXFLAGS=["-fexceptions"])
|
|
|
|
env_thirdparty = env_metal.Clone()
|
|
env_thirdparty.disable_warnings()
|
|
env_thirdparty.add_source_files(thirdparty_obj, thirdparty_sources)
|
|
env_metal.drivers_sources += thirdparty_obj
|
|
|
|
# Enable C++20 for the Objective-C++ Metal code, which uses C++20 concepts.
|
|
if "-std=gnu++17" in env_metal["CXXFLAGS"]:
|
|
env_metal["CXXFLAGS"].remove("-std=gnu++17")
|
|
env_metal.Append(CXXFLAGS=["-std=gnu++20"])
|
|
|
|
# Enable module support
|
|
env_metal.Append(CCFLAGS=["-fmodules", "-fcxx-modules"])
|
|
|
|
# Driver source files
|
|
|
|
driver_obj = []
|
|
|
|
env_metal.add_source_files(driver_obj, "*.cpp")
|
|
env.drivers_sources += driver_obj
|
|
|
|
# Needed to force rebuilding the driver files when the thirdparty library is updated.
|
|
env.Depends(driver_obj, thirdparty_obj)
|